HitBlock-Mega65/level.asm at master · GeorgRottensteiner/HitBlock-Mega65 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
!zone BuildScreen
.PREVIOUS_BLOCK
          !byte $ff

BuildScreen
          jsr SetupScreenVector

          ldy LEVEL_NR
          lda MAPS_LO,y
          sta ZEROPAGE_POINTER_1
          lda MAPS_HI,y
          sta ZEROPAGE_POINTER_1 + 1

          lda SCREENS_MAP_EXTRA_DATA_LIST_LO,y
          sta ZEROPAGE_POINTER_2
          lda SCREENS_MAP_EXTRA_DATA_LIST_HI,y
          sta ZEROPAGE_POINTER_2 + 1

          ldy #0
          lda (ZEROPAGE_POINTER_2),y
          asl
          sta PLAYER_START_X
          iny
          lda (ZEROPAGE_POINTER_2),y
          asl
          sta PLAYER_START_Y
          iny
          lda (ZEROPAGE_POINTER_2),y
          sta PLAYER_COLOR

          lda #$ff
          sta .PREVIOUS_BLOCK

          ldy #0
          sty NUM_BLOCKS
          ldx #0
-
          lda #1
          sta PARAM1

          lda (ZEROPAGE_POINTER_1),y
          bpl .SetTile

          ;RLE, MSB set, rest is count
          and #$7f
          sta PARAM1

          iny
          lda (ZEROPAGE_POINTER_1),y

.SetTile
          sta LEVEL_DATA,x

          ;count blocks to destroy
          cmp #TILE_GREY
          beq .AddTile
          cmp #TILE_BLUE
          bcc +

          cmp #TILE_BROWN + 1
          bcs +

.AddTile
          inc NUM_BLOCKS

+

          dec PARAM1
          beq .RLEDone

          inx
          jmp .SetTile

.RLEDone

          iny
          inx
          cpx #240
          bne -

          ;fix shadows
          ldy #21
--
          jsr FixTileShadow

          iny
          cpy #20 * 12
          bne --


          lda #<LEVEL_DATA
          sta ZEROPAGE_POINTER_1
          lda #>LEVEL_DATA
          sta ZEROPAGE_POINTER_1 + 1

          ldz #$00
          lda #0
          sta PARAM2

.NextLine
          lda #0
          ldz #0
          sta PARAM1

          ;ldy PARAM2
          ;lda SCREEN_LINE_OFFSET_TABLE_LO,y
          ;sta ZEROPAGE_POINTER_2
          ;lda SCREEN_LINE_OFFSET_TABLE_HI,y
          ;sta ZEROPAGE_POINTER_2 + 1

.NextTile
          ldy PARAM1
          lda (ZEROPAGE_POINTER_1),y
          tax

          ;UL
          lda SCREENS_TILE_CHARS_0_0,x
          sta [ZP.Screen], z
          inz
          inz
          bne +
          inc ZP.Screen + 1
+


          ;UR
          lda SCREENS_TILE_CHARS_1_0,x
          sta [ZP.Screen], z
          inz
          inz
          bne +
          inc ZP.Screen + 1
+

          inc PARAM1
          lda PARAM1
          cmp #20
          bne .NextTile


          ;lower half of tiles
          lda ZP.Screen
          clc
          adc #80
          sta ZP.Screen
          bcc +
          inc ZP.Screen + 1
+

          inc PARAM2
          ;ldy PARAM2
          ;lda SCREEN_LINE_OFFSET_TABLE_LO,y
          ;sta ZEROPAGE_POINTER_2
          ;lda SCREEN_LINE_OFFSET_TABLE_HI,y
          ;sta ZEROPAGE_POINTER_2 + 1

          lda #0
          taz
          sta PARAM1

.NextTile2
          ldy PARAM1
          lda (ZEROPAGE_POINTER_1),y
          tax

          ;LL
          lda SCREENS_TILE_CHARS_0_1,x
          sta [ZP.Screen], z
          inz
          inz
          bne +
          inc ZP.Screen + 1
+


          ;LR
          lda SCREENS_TILE_CHARS_1_1,x
          sta [ZP.Screen], z
          inz
          inz
          bne +
          inc ZP.Screen + 1
+

          inc PARAM1
          lda PARAM1
          cmp #20
          bne .NextTile2

          ;next line
          lda #0
          sta PARAM1

          lda ZP.Screen
          clc
          adc #80
          sta ZP.Screen
          bcc +
          inc ZP.Screen + 1
+
          lda ZEROPAGE_POINTER_1
          clc
          adc #20
          sta ZEROPAGE_POINTER_1
          bcc +
          inc ZEROPAGE_POINTER_1 + 1
+

          inc PARAM2
          lda PARAM2
          cmp #24
          lbne .NextLine


          rts


!zone FixTileShadow
;expect y is tile index in LEVEL_DATA
FixTileShadow
          lda LEVEL_DATA,y
          jsr IsTileBlocking
          bne .TileIsNotBlocking

          ;blocking tile have no shadows
          ;combine shadow data
          ;tile to the left
          lda LEVEL_DATA - 1,y
          jsr IsTileBlocking
          sta PARAM11

          ;tile to the top
          lda LEVEL_DATA - 20,y
          jsr IsTileBlocking
          asl
          ora PARAM11
          sta PARAM11

          ;tile to the top left
          lda LEVEL_DATA - 21,y
          jsr IsTileBlocking
          asl
          asl
          ora PARAM11
          sta PARAM11

          tax
          lda TILE_SHADOW_TABLE,x
          sta LEVEL_DATA,y

.TileIsNotBlocking
          rts


!zone IsTileBlocking
;a = tile index
;returns 1 if blocking, 0 if non blocking
IsTileBlocking
          cmp #TILE_EMPTY_SHADOW_7 + 1
          bcc .NotBlocking

          lda #1
          rts

.NotBlocking
          lda #0
          rts


;xxxx xABC
;            A = tile to top left is blocking
;            B = tile above is blocking
;            C = tile to left is blocking
TILE_SHADOW_TABLE
          !byte TILE_EMPTY      ;no blocking
          !byte TILE_EMPTY_SHADOW_5   ;blocked left
          !byte TILE_EMPTY_SHADOW_1   ;blocked top
          !byte TILE_EMPTY_SHADOW_6   ;blocked top, left
          !byte TILE_EMPTY_SHADOW_3   ;blocked top left
          !byte TILE_EMPTY_SHADOW_4   ;blocked left, top left
          !byte TILE_EMPTY_SHADOW_2   ;blocked top, top left
          !byte TILE_EMPTY_SHADOW_7   ;blocked top, left, top left


;!mediasrc "levels.mapproject",SCREENS_,maptile

!src "stages.asm"

!mediasrc "levels.mapproject",SCREENS_,tile
!mediasrc "levels.mapproject",SCREENS_,mapextradata

LEVEL_NR
          !byte 0

;LEVEL_DATA_OUTSIDE
          !fill 21, TILE_STEEL
LEVEL_DATA
          !fill 240

;LEVEL_DATA_OUTSIDE
          !fill 21, TILE_STEEL