-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathmath.inc
More file actions
431 lines (335 loc) · 16.3 KB
/
math.inc
File metadata and controls
431 lines (335 loc) · 16.3 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
nolist
#ifndef MATH_INC
#define MATH_INC
;**********************************************************************
; *
; Description: Arithmetic helper macros. *
; *
; Author: Chris White (whitecf69@gmail.com) *
; *
; Copyright (C) 2011 by Monitor Computing Services Limited, licensed *
; under CC BY-NC-SA 4.0. To view a copy of this license, visit *
; https://creativecommons.org/licenses/by-nc-sa/4.0/ *
; *
; This program is distributed in the hope that it will be useful, but *
; WITHOUT ANY WARRANTY; without even the implied warranty of *
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. *
; *
;**********************************************************************
;**********************************************************************
; *
; Macro: Mul8x8 *
; *
; 8 bit by 8 bit multiply giving 16 bit result *
; *
; Arguments: W register - 8 bit multiplicand - undamaged *
; Mulplr - 8 bit multiplier - destroyed *
; ResLow - Result low byte *
; ResHigh - Result high byte *
; *
;**********************************************************************
Mul8x8 macro Mulplr, ResLow, ResHigh
local Loop, EndMul
; Clear result
clrf ResHigh
clrf ResLow
; Set carry bit, rotated into multiplier and ensures 8 loop iterations
bsf STATUS,C
Loop ; Rotate multiplier 1 bit right, carry -> bit 7, bit 0 -> carry
rrf Mulplr,F
; Test if multiplier now == 0, if so multiply is finished
movf Mulplr,F
btfsc STATUS,Z
goto EndMul
; Test carry, if set add multiplicand to result high byte
btfsc STATUS,C
addwf ResHigh,F
; Rotate result right (/ by 2), as ResLow was cleared this also clears carry
rrf ResHigh,F
rrf ResLow,F
goto Loop
EndMul
endm
;**********************************************************************
; *
; Macro: Mul16x8 *
; *
; 16 bit by 8 bit multiply giving 24 bit result *
; NOTE - contents of W are destroyed *
; *
; Arguments: Mulplr - 8 bit multiplier - destroyed *
; MulpLow - 16 bit multiplicand low byte - undamaged *
; MulpHigh - 16 bit multiplicand high byte - undamaged *
; ResLow - Result low byte *
; ResMid - Result mid byte *
; ResHigh - Result high byte *
; *
;**********************************************************************
Mul16x8 macro Mulplr, MulpLow, MulpHigh, ResLow, ResMid, ResHigh
local Loop, LoopMul, EndMul
; Clear result
clrf ResHigh
clrf ResMid
clrf ResLow
; Set carry bit, this is rotated into multiplier and ensures 8 loop iterations
bsf STATUS,C
Loop ; Rotate multiplier 1 bit right, carry -> bit 7, bit 0 -> carry
rrf Mulplr,F
; Test if multiplier now == 0, if so multiply is finished
movf Mulplr,F
btfsc STATUS,Z
goto EndMul
; Test carry, if set add multiplicand to result high byte
btfss STATUS,C
goto LoopMul
Add16 MulpLow, MulpHigh, ResMid, ResHigh
; Rotate result right (/ by 2), as ResLow was cleared this also clears carry
LoopMul rrf ResHigh,F
rrf ResMid,F
rrf ResLow,F
goto Loop
EndMul
endm
;**********************************************************************
; *
; Macro: Mul16x8R *
; *
; 16 bit by 8 bit multiply restricted to 16 bit result *
; NOTE - contents of W are destroyed *
; *
; Arguments: Mulplr - 8 bit multiplier - destroyed *
; MulpLow - 16 bit multiplicand low byte - undamaged *
; MulpHigh - 16 bit multiplicand high byte - undamaged *
; ResLow - Result low byte *
; ResMid - Result mid byte *
; ResHigh - Result high byte - cleared *
; *
;**********************************************************************
Mul16x8R macro Mulplr, MulpLow, MulpHigh, ResLow, ResMid, ResHigh
local NoOverflow
Mul16x8 Mulplr, MulpLow, MulpHigh, ResLow, ResMid, ResHigh
movf ResHigh,F
btfsc STATUS,Z
goto NoOverflow
movlw 0xFF
movwf ResLow
movwf ResMid
clrf ResHigh
NoOverflow
endm
;**********************************************************************
; *
; Macro: Add16 *
; *
; 16 bit add giving 16 bit result *
; NOTE - contents of W are destroyed *
; STATUS,C returns carry status *
; *
; Arguments: AddLow - 1st Number low byte - undamaged *
; AddHigh - 1st Number high byte - undamaged *
; ResLow - 2nd Number low byte - set to result *
; ResHigh - 2nd Number high byte - set to result *
; *
;**********************************************************************
Add16 macro AddLow, AddHigh, ResLow, ResHigh
local HighAdd, EndAdd
; Add low bytes
movf AddLow,W
addwf ResLow,F
movf AddHigh,W
btfss STATUS,C
; No carry generated by low byte addition, simply add high bytes
goto HighAdd
; Carry generated by low byte addition, add to high bytes
addlw 1
btfsc STATUS,C
; Low byte carry has caused AddHigh to overflow to zero,
; leave ResHigh unaltered and carry flag set
goto EndAdd
HighAdd ; Add high bytes
addwf ResHigh,F
EndAdd
endm
;**********************************************************************
; *
; Macro: Add24 *
; *
; 24 bit add giving 24 bit result *
; NOTE - contents of W are destroyed *
; STATUS,C returns carry status *
; *
; Arguments: AddLow - 1st Number low byte - undamaged *
; AddMid - 1st Number mid byte - undamaged *
; AddHigh - 1st Number high byte - undamaged *
; ResLow - 2nd Number low byte - set to result *
; ResMid - 2nd Number mid byte - set to result *
; ResHigh - 2nd Number high byte - set to result *
; *
;**********************************************************************
Add24 macro AddLow, AddMid, AddHigh, ResLow, ResMid, ResHigh
local HighAdd, EndAdd
; Add low word
Add16 AddLow, AddMid, ResLow, ResMid
movf AddHigh,W
btfss STATUS,C
; No carry generated by low byte addition, simply add high bytes
goto HighAdd
; Carry generated by low byte addition, add to high bytes
addlw 1
btfsc STATUS,C
; Low byte carry has caused AddHigh to overflow to zero,
; leave ResHigh unaltered and carry flag set
goto EndAdd
HighAdd ; Add high bytes
addwf ResHigh,F
EndAdd
endm
;**********************************************************************
; *
; Macro: Sub16 *
; *
; 16 bit subtract giving 16 bit result *
; NOTE - contents of W are destroyed *
; STATUS,C returns 0 -ve result, 1 +ve result *
; *
; Arguments: SubLow - 1st Number low byte - undamaged *
; SubHigh - 1st Number high byte - undamaged *
; ResLow - 2nd Number low byte - set to result *
; ResHigh - 2nd Number high byte - set to result *
; *
;**********************************************************************
Sub16 macro SubLow, SubHigh, ResLow, ResHigh
local HighSub, EndSub
; Subtract low bytes
movf SubLow,W
subwf ResLow,F
movf SubHigh,W
btfsc STATUS,C
; Carry set - result positive, simply subtract high bytes
goto HighSub
; Low byte needs to borrow from high bytes
addlw 1
btfss STATUS,C
goto HighSub
; Low byte borrow has caused SubHigh to overflow to zero,
; leave ResHigh unaltered and carry flag set (= -ve result)
bcf STATUS,C
goto EndSub
HighSub ; Subtract high bytes
subwf ResHigh,F
EndSub
endm
;**********************************************************************
; *
; Macro: Sub24 *
; *
; 24 bit subtract giving 24 bit result *
; NOTE - contents of W are destroyed *
; STATUS,C returns 0 -ve result, 1 +ve result *
; *
; Arguments: SubLow - 1st Number low byte - undamaged *
; SubMid - 1st Number mid byte - undamaged *
; SubHigh - 1st Number high byte - undamaged *
; ResLow - 2nd Number low byte - set to result *
; ResMid - 2nd Number mid byte - set to result *
; ResHigh - 2nd Number high byte - set to result *
; *
;**********************************************************************
Sub24 macro SubLow, SubMid, SubHigh, ResLow, ResMid, ResHigh
local HighSub, EndSub
; Subtract low word
Sub16 SubLow, SubMid, ResLow, ResMid
movf SubHigh,W
btfsc STATUS,C
; Carry set - result positive, simply subtract high bytes
goto HighSub
; Low word needs to borrow from high bytes
addlw 1
btfss STATUS,C
goto HighSub
; Low word borrow has caused SubHigh to overflow to zero,
; leave ResHigh unaltered and carry flag set (= -ve result)
bcf STATUS,C
goto EndSub
HighSub ; Subtract high bytes
subwf ResHigh,F
EndSub
endm
;**********************************************************************
; *
; Macro: Int8x16 *
; *
; Interpolate 8 bit value using over 16 discrete ranges *
; giving a 12 bit result *
; NOTE - contents of W are destroyed *
; *
; Arguments: Value - value to interpolate - undamaged *
; TempAcc8 - temporary accumulator - destroyed *
; IntTable - interpolation table base - undamaged *
; TempAccL - temporary low byte - destroyed *
; TempAccH - temporary high byte - destroyed *
; ResLow - 2nd temporary low byte - set to result *
; ResHigh - 2nd temporary high byte - set to result *
; *
;**********************************************************************
Int8x16 macro Value, TempAcc8, IntTable, TempAccL, TempAccH, ResLow, ResHigh
swapf Value,W ; Get high nibble of value ...
andlw 0x0F ; ... into low nibble, isolate, ...
addlw LOW IntTable ; ... add to table start ...
movwf FSR ; ... load as indirect address
movf INDF,W ; Get lower ...
movwf TempAcc8 ; ... range bound
movf Value,W ; Get value ...
andlw 0x0F ; ... low nibble ...
sublw 0x10 ; ... and subtract it from 16
; Multiply: W = 16 - value low nibble
; by: TempAcc8 = range lower bound
Mul8x8 TempAcc8, ResLow, ResHigh
incf FSR,F ; Increment indirect address
movf INDF,W ; Get upper ...
movwf TempAcc8 ; ... range bound
movf Value,W ; Get value ...
andlw 0x0F ; ... low nibble
; Multiply: W = value low nibble
; by: TempAcc8 = range upper bound
Mul8x8 TempAcc8, TempAccL, TempAccH
; Add range upper and lower range contributions
Add16 TempAccL, TempAccH, ResLow, ResHigh
endm
;**********************************************************************
; *
; Macro: Div24x8 *
; *
; 24 bit by 8 bit multiply giving 24 bit result *
; NOTE - contents of W are destroyed *
; *
; Arguments: W - 8 bit divisor - undamaged *
; Counter - Division loop counter - destroyed *
; TempAcc - Temporary register - destroyed *
; DivLow - Dividend (and result) low byte *
; DivMid - Dividend (and result) mid byte *
; DivHigh - Dividend (and result) high byte *
; *
;**********************************************************************
Div24x8 macro Counter, TempAcc, DivLow, DivMid, DivHigh
local Loop, Itterate
clrf TempAcc
clrf Counter ; Set counter for 25 itterations
bsf Counter,4
bsf Counter,3
bsf Counter,0
Loop ; Rotate dividend 1 bit left, carry -> bit 0, bit 24 -> carry
rlf DivLow,F
rlf DivMid,F
rlf DivHigh,F
rlf TempAcc,F
subwf TempAcc,F
btfsc STATUS,C
goto Itterate
addwf TempAcc,F
bcf STATUS,C
Itterate decfsz Counter,F
goto Loop
endm
#endif
list