2600bas.native.bat

@echo off
REM 2600basic compilation script (Native Windows executables)

setlocal

if X"%bB%"==X goto nobasic

echo Using bB=%bB%

REM --- Display tool versions ---
for /F "delims=" %%v in ('"%bB%\2600basic.exe" -v 2^>nul') do set BASVER=%%v
echo   basic version: %BASVER%
for /F "delims=" %%v in ('"%bB%\dasm.exe" 2^>nul') do set DASMVER=%%v & goto dasmgotver
:dasmgotver
echo   dasm version: %DASMVER%


REM --- Source file check ---
if "%~1"=="" (
    echo ### ERROR: No source file specified.
    exit /b 1
)

if /i "%~1"=="-v" (
    REM Just version check
    exit /b 0
)

set srcfile=%~nx1
set srcbase=%~n1
set srcdir=%~dp1
if "%srcdir:~-1%"=="\" set srcdir=%srcdir:~0,-1%

echo.
echo Starting build of %srcfile%

REM --- Preprocess and Compile ---
"%bB%\preprocess.exe" <"%~f1" | "%bB%\2600basic.exe" -i "%bB%" > bB.asm
if errorlevel 1 goto basicerror

REM --- Postprocess / Optimize ---
if /I "%2"=="-O" (
    "%bB%\postprocess.exe" -i "%bB%"  ^
    | "%bB%\optimize.exe" > "%~1.asm"
) else (
    "%bB%\postprocess.exe" -i "%bB%" > "%~1.asm"
)

REM --- Assemble final binary ---
"%bB%\dasm.exe" "%~1.asm" -I. -I"%bB%\includes" -f3 -p20 -l"%~1.lst" -s"%~1.sym" -o"%~1.bin" | "%bB%\bbfilter.exe"

REM --- Create an ACE file if the binary is DPC+ ---
"%bB%\relocateBB.exe" "%~nx1.bin"

REM --- Create a .elf file to flash PXE games to Chameleon Cart
if not defined PXE_VENDOR_UUID (
    for /F "delims=" %%A IN ('powershell -command [guid]::NewGuid(^).ToString(^)') DO (
        SET "PXE_VENDOR_UUID=%%A"
    )
)
FOR /F "delims=" %%A IN ('powershell -command [guid]::NewGuid(^).ToString(^)') DO (
    SET "GameGuid=%%A"
)
"%bB%\pxebin2ccelf.exe" "%~nx1.bin" "%bB%\includes\PXE_CC_pre.arm" "%bB%\includes\PXE_CC_post.arm" "%PXE_VENDOR_UUID%" "%GameGuid%"

goto end

:basicerror
echo.
echo ### ERROR: 2600basic compilation failed.
exit /b 1

:nobasic
echo.
echo ### ERROR: bB not defined.
exit /b 1

:end
endlocal
exit /b 0