playcode/pc.lark at main · asyncze/playcode · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

program     : (taggable | tag_stmt | swap_stmt | if_stmt | while_stmt | assert_stmt | print_stmt)*

taggable    : (TAG)? assign_stmt

assign_stmt : identifier "=" (vector | expr)

tag_stmt    : TAG

swap_stmt   : "swap" identifier identifier

if_stmt     : "if" comparison "{" (program)* "}" ("else" "{" (program)* "}")?

while_stmt  : "while" comparison "{" (program)* "}"

assert_stmt : identifier assert

print_stmt  : "print" comparison (assert)?

comparison  : expr
            | expr "==" comparison      -> eq
            | expr "!=" comparison      -> neq
            | expr "<" comparison       -> lt
            | expr ">" comparison       -> gt

expr        : term
            | term "+" expr             -> add
            | term "-" expr             -> sub

term        : factor
            | factor "*" term           -> mul
            | factor "/" term           -> div

factor      : SIGNED_NUMBER             -> number
            | identifier
            | "True"                    -> true
            | "False"                   -> false
            | "(" expr ")"

identifier  : CNAME ("[" expr "]")?

vector      : "[" (expr ("," expr)*)? "]"

assert      : "->" STRING

TAG         : /@[a-zA-Z_]+/

COMMENT     : "--" /[^\n]*/

%import common.ESCAPED_STRING -> STRING
%import common.CNAME
%import common.SIGNED_NUMBER
%import common.WS

%ignore WS
%ignore COMMENT