AutoHotkeyScripts/lib/Shell.ahk at main · chenyyoung/AutoHotkeyScripts · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
/*
@Members https://learn.microsoft.com/en-us/windows/win32/shell/folderitems
@Example firstItemPath := Shell_GetSelectedFolderItems().Item(0).Path
*/
Shell_GetSelectedFolderItems() {
    if folderView := Shell_GetActiveFolderView()
        return folderView.SelectedItems
}

/*
@Members https://learn.microsoft.com/en-us/windows/win32/shell/folderitem
@Example foucusedItemName := Shell_GetFocusedFolderItem().Name
*/
Shell_GetFocusedFolderItem() {
    if folderView := Shell_GetActiveFolderView()
        return folderView.FocusedItem
}

/*
@Members https://learn.microsoft.com/en-us/windows/win32/shell/folderitem
@Example activeFolderPath := Shell_GetActiveFolder().Path
*/
Shell_GetActiveFolder() {
    if folderView := Shell_GetActiveFolderView()
        return folderView.Folder.Self
}

/*
@Members https://learn.microsoft.com/en-us/windows/win32/shell/shellfolderview
@Example foucusedItemSize := Shell_GetActiveFolderView().FocusedItem.Size
*/
Shell_GetActiveFolderView() {
    hwndFore := WinExist("A")
    windows := ComObject("{9BA05972-F6A8-11CF-A442-00A0C90A8F39}")
    for webBrowser in windows
        if webBrowser.Hwnd == hwndFore
            return webBrowser.Document
    hwndBuf := Buffer(4)
    if webBrowser := windows.FindWindowSW(0, 0, 8, ComValue(0x4003, hwndBuf.Ptr), 1) {
        hwndDesktop := NumGet(hwndBuf, "int")
        if hwndFore == hwndDesktop
            return webBrowser.Document
        if WinGetClass(hwndFore) == "WorkerW" {
            hwndFocus := ControlGetFocus(hwndFore)
            if hwndFocus && WinGetClass(hwndFocus) == "SysListView32"
                return webBrowser.Document
        }
    }
}

/*
@Members https://learn.microsoft.com/en-us/windows/win32/shell/folderitem
@Example firstFolderPath := Shell_GetAllOpenedFolders()[1].Path
*/
Shell_GetAllOpenedFolders() {
    folders := []
    for webBrowser in ComObject("{9BA05972-F6A8-11CF-A442-00A0C90A8F39}")
        folders.Push(webBrowser.Document.Folder.Self)
    return folders
}

Shell_UnZipFileTo(src, dest) {
    shell := ComObject("Shell.Application")
    dest := shell.NameSpace(dest)
    src := shell.NameSpace(src)
    dest.CopyHere(src.Items, 4)
}