WireTypeScriptGenerator/build.gradle.kts at main · efirestone/WireTypeScriptGenerator · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
val artifactGroup = "com.codellyrandom.wiretypescriptgenerator"
val artifactVersion = "0.5.1"

group = artifactGroup
version = artifactVersion

plugins {
    kotlin("jvm") version "2.0.20"
    id("java")
    id("maven-publish")
    id("signing")
}

dependencies {
    implementation(kotlin("stdlib:2.0.20"))
    implementation("com.squareup.wire:wire-compiler:5.1.0")
    testImplementation(kotlin("test-junit:1.9.25"))
}

repositories {
    mavenCentral()
}

java {
    withJavadocJar()
    withSourcesJar()
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

publishing {
    publications {
         create<MavenPublication>("mavenJava") {
            groupId = artifactGroup
            artifactId = "wire-typescript-generator"
            version = artifactVersion

            from(components["java"])
            pom {
                name.set("Wire TypeScript Generator")
                description.set("Generates TypeScript type definitions from protobuf files, using Wire.")
                url.set("https://github.com/efirestone/WireTypeScriptGenerator")
                licenses {
                    license {
                        name.set("The Apache License, Version 2.0")
                        url.set("https://www.apache.org/licenses/LICENSE-2.0.txt")
                    }
                }
                developers {
                    developer {
                        id.set("efirestone")
                        name.set("Eric Firestone")
                    }
                }
                scm {
                    url.set("https://github.com/efirestone/WireTypeScriptGenerator")
                    connection.set("scm:git:https://github.com/efirestone/WireTypeScriptGenerator.git")
                    developerConnection.set("scm:git:ssh://git@github.com:efirestone/WireTypeScriptGenerator.git")
                }
            }
        }
    }
    repositories {
        maven {
            // Once published, visit https://s01.oss.sonatype.org/#stagingRepositories to release the artifact.
            val releasesRepoUrl = uri("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2")
            val snapshotsRepoUrl = uri("https://s01.oss.sonatype.org/content/repositories/snapshots")
            url = if (version.toString().endsWith("SNAPSHOT")) snapshotsRepoUrl else releasesRepoUrl
            credentials {
                username = properties["nexusUsername"] as String
                password = properties["nexusPassword"] as String
            }
        }
    }
}

signing {
    sign(publishing.publications["mavenJava"])
}