haskell-algorithms/flake.nix at main · prsteele/haskell-algorithms · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
{
  description = "Common data structures and algorithms";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.11";
    systems.url = "github:nix-systems/default";
  };

  outputs = { self, nixpkgs, systems, ... }:
    let
      forAllSystems = nixpkgs.lib.genAttrs (import systems);
      mkPkgs = system: import nixpkgs { inherit system; overlays = [ self.overlays.default ]; };
    in
    {
      packages = forAllSystems
        (system:
          let
            pkgs = mkPkgs system;
          in
          {
            default = pkgs.haskellPackages.haskell-algorithms;

            format = pkgs.writeShellApplication {
              name = "format";
              runtimeInputs = [ pkgs.git pkgs.ormolu pkgs.findutils ];
              text = ''
                git ls-files -z '*.hs' | xargs -0 -I{} ormolu --mode inplace {}
              '';
            };

            check-formatting = pkgs.writeShellApplication {
              name = "format";
              runtimeInputs = [ pkgs.git pkgs.ormolu pkgs.findutils ];
              text = ''
                git ls-files -z '*.hs' | xargs -0 -I{} ormolu --mode check {}
              '';
            };
          }
        );

      devShells = forAllSystems (system:
        let
          pkgs = mkPkgs system;
        in
        {
          default = pkgs.haskellPackages.shellFor {
            packages =
              let
                enableBench = pkgs.haskell.lib.compose.overrideCabal (drv: { doBenchmark = true; });
              in
              hpkgs: [ (enableBench hpkgs.haskell-algorithms) ];

            buildInputs = [
              pkgs.haskellPackages.haskell-language-server
              pkgs.ormolu
              pkgs.cabal-install
            ];

            withHoogle = true;
            doBenchmark = true;
          };
        }
      );

      overlays = {
        default = final: prev: {
          haskellPackages = prev.haskellPackages.override {
            overrides = hfinal: hprev: {
              haskell-algorithms = hfinal.callCabal2nix "haskell-algorithms" self { };
            };
          };
        };
      };
    };
}