python-pylontech/flake.nix at master · pshirshov/python-pylontech · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
{
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/release-25.05";

  inputs.flake-utils.url = "github:numtide/flake-utils";

  inputs.pyproject-nix = {
    url = "github:pyproject-nix/pyproject.nix";
    inputs.nixpkgs.follows = "nixpkgs";
  };

  inputs.uv2nix = {
    url = "github:pyproject-nix/uv2nix";
    inputs.pyproject-nix.follows = "pyproject-nix";
    inputs.nixpkgs.follows = "nixpkgs";
  };

  inputs.pyproject-build-systems = {
    url = "github:pyproject-nix/build-system-pkgs";
    inputs.pyproject-nix.follows = "pyproject-nix";
    inputs.uv2nix.follows = "uv2nix";
    inputs.nixpkgs.follows = "nixpkgs";
  };

  # ( printf "~20024642E00202FD33\r"; sleep 1 ) | nc 192.168.10.237 23
  outputs =
    { self
    , nixpkgs
    , flake-utils
    , uv2nix
    , pyproject-nix
    , pyproject-build-systems
    , ...
    }:
    flake-utils.lib.eachDefaultSystem
      (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          config.allowUnfree = true;
        };
        lib = pkgs.lib;
        rustManifest = lib.importTOML ./rust-mqtt-adapter/Cargo.toml;
     workspace = uv2nix.lib.workspace.loadWorkspace { workspaceRoot = ./.; };

      overlay = workspace.mkPyprojectOverlay {
        sourcePreference = "wheel"; # or sourcePreference = "sdist";
      };

      pyprojectOverrides = _final: _prev: {
      };

      python = pkgs.python313;

      pythonSet =
        (pkgs.callPackage pyproject-nix.build.packages {
          inherit python;
        }).overrideScope
          (
            lib.composeManyExtensions [
              pyproject-build-systems.overlays.default
              overlay
              pyprojectOverrides
            ]
          );
      rustMqttAdapter = pkgs.rustPlatform.buildRustPackage {
        pname = rustManifest.package.name;
        version = rustManifest.package.version;
        src = ./rust-mqtt-adapter;
        cargoLock.lockFile = ./rust-mqtt-adapter/Cargo.lock;
      };
      in
      {
        devShells.default = pkgs.mkShell {
          nativeBuildInputs = with pkgs.buildPackages; [
            git
            socat
            uv
            cargo
            rustc
            rustfmt

            (python313.withPackages (python-pkgs: [
              python-pkgs.pyserial
              python-pkgs.construct
              python-pkgs.standard-telnetlib
              python-pkgs.rich
            ]))
          ];
        };

     packages.default = pythonSet.mkVirtualEnv "pylontechpoller-env" workspace.deps.default;
        packages.pylontech-mqtt-adapter = rustMqttAdapter;

        apps.default = {
          type = "app";
          program = "${self.packages."${system}".default}/bin/poller";
        };
        apps.pylontech-mqtt-adapter = {
          type = "app";
          program = "${self.packages."${system}".pylontech-mqtt-adapter}/bin/pylontech-mqtt-adapter";
        };
      }
      );


}